Как правильно разбить число... ASM + AVR

wofs

Доброго дня.
Есть некая переменная

Код:

      .DSEG
ICNT:   .byte    1

Допустим в ней число 0xA5 (165 в десятичной).
загоняю байты в регистры

Код:

LDS R16,ICNT

Вопрос.
как сделать так, что бы в регистры R17,R18,R19 поместились числа 0x01,0x06,0x05 соответственно ?
Понимаю что посредством деления с остатком, но как? Если не затруднит, приведите коротенький кусок кода на ASM...

notfreeuser

Код:

.include <m8def.inc>

.def   tmp = R16
.def   BCDH = R17               
.def   BCDL = R18               

            
      ldi r16, low(RAMEND)      
      ldi r17, high(RAMEND)
      out SPH, r17
      out SPL, r16


      ldi BCDL, 165
      rcall bin8toBCD            ; 165 / 10 = 16, 5 в остатке (едениц)
      mov r19, BCDL
      mov BCDL, BCDH            
      rcall bin8toBCD            ; 16 / 10 = 1 (сотни), 6 в остатке (десатков)

      rjmp PC

bin8toBCD:                     
      ldi tmp, 10               ; будем делить на 10
      ldi BCDH, -1            
BCD_loop:                     
      inc BCDH               ; считаем сколько раз отнимали 10
      sub BCDL, tmp
      brsh BCD_loop            ; переход если результат еще больше 0
      add BCDL, tmp            ; откат назад если результат <0

      ret 

THE BEAST

Поищите, я как то выкладывал различные деления без этих дурацких игр с вычитанием.

wofs

to notfreeuser спасибо большое!!! в копилку!
to THE BEAST поищу, полезно иметь несколько вариантов решений одной задачи

Горнист

wofs писал(а):

Понимаю что посредством деления с остатком, но как? Если не затруднит, приведите коротенький кусок кода на ASM...

C:\Program Files\Atmel\AVR Tools\AvrAssembler\Appnotes\avr204.asm

wofs

to Горнист и вас благодарю.
p.s. еще нарыл такой способ:

Код:

;by singlskv (c)
;Input:  r16 - 8bit Binary
;Output: r18:r17:r16 unpacked BCD

    ldi     r17,164
    mul     r16,r17
    clr     r18
    lsl     r0
    rol     r1
    rol     r18
    lsl     r0
    rol     r1
    rol     r18
    inc     r1
    ldi     r16,10
    mul     r1,r16
    mov     r17,r1
    mul     r0,r16
    mov     r16,r1

Горнист

Ещё есть нихонский дядька Элм Чен, к нему тоже иногда бывает полезно заглядывать в поисках алгоритмов. http://elm-chan.org/cc_e.html

Easyelectronics.ru

Как правильно разбить число... ASM + AVR

Кто сейчас на конференции